Initial Add

2021-06-05 16:26:07 -04:00
parent d768b3013a
commit 5a0fede9cc
4 changed files with 113 additions and 0 deletions
@@ -0,0 +1,53 @@
+GRP: +
+  PGM
+/*==============================================================*/
+/* Start-up group jobs suitable for a programmer.               */
+/*==============================================================*/
+
+  DCL VAR(&DFTLIBLPGM) TYPE(*CHAR) LEN(10)    VALUE('GRP_LIBL')
+  DCL VAR(&DFTLIBLLIB) TYPE(*CHAR) LEN(10)    VALUE('LENNONS1')
+
+  CHGJOB CCSID(37)
+
+/*=== Set my library list ======================================*/
+  CALL PGM(&DFTLIBLLIB/&DFTLIBLPGM)
+
+/*=== Set QPQXPRTF to a sensible line length ===================*/
+/* Defined by IBM as 80--132 is more practical */
+  OVRPRTF FILE(QPQXPRTF) PAGESIZE(*N 132)
+
+/*=== Change this job to a group job ===========================*/
+  CHGGRPA GRPJOB(QCMD__1) TEXT('QCMD - 1')
+  MONMSG MSGID(CPF1305) /* Already a group job with a name */
+
+/*=== Start other group jobs. Command to run is in *GDA ========*/
+/* Each job runs GRP_INIT which immediately transfers back */
+
+  CHGDTAARA DTAARA(*GDA) VALUE('GO ASSIST')
+  TFRGRPJOB GRPJOB(ASSIST) INLGRPPGM(*LIBL/GRP_INIT) TEXT('Oper+
+     ational Assistant')
+
+  CHGDTAARA DTAARA(*GDA) VALUE('Call QCMD')
+  TFRGRPJOB GRPJOB(QCMD__2) INLGRPPGM(*LIBL/GRP_INIT) TEXT('QCMD - 2')
+
+  CHGDTAARA DTAARA(*GDA) VALUE(STRPDM)
+  TFRGRPJOB GRPJOB(PDM_2) INLGRPPGM(*LIBL/GRP_INIT) TEXT('PDM - 2')
+
+  CHGDTAARA DTAARA(*GDA) VALUE(STRPDM)
+  TFRGRPJOB GRPJOB(PDM_1) INLGRPPGM(*LIBL/GRP_INIT) TEXT('PDM - 1')
+
+/*=== Set my own attention program for this job ================*/
+  SETATNPGM PGM(*LIBL/GRP_ATN)
+
+/*=== Any jobs added with F6 will start in QCMD ================*/
+  CHGDTAARA DTAARA(*GDA) VALUE('Call QCMD')
+
+/*=== Start QCMD for this job ==================================*/
+/* On F3 from QCMD, cleans up environment and loops back */
+LOOP: +
+  CALL PGM(QCMD)
+  RCLRSC
+  RCLACTGRP ACTGRP(*ELIGIBLE) /* May not be a good practice */
+  GOTO CMDLBL(LOOP)
+
+  ENDPGM
@@ -0,0 +1,11 @@
+GR_ATN: +
+  PGM
+/*=== Attention program for programmer group job ============== */
+/* Pops up an an ugly, but effective, IBM selection menu.       */
+/* Called when Attn key is pressed in a group job.              */
+/* Attn is Shift+Esc in most emulators.                         */
+/*==============================================================*/
+
+  TFRGRPJOB GRPJOB(*SELECT)
+
+  ENDPGM
@@ -0,0 +1,40 @@
+GR_INIT: +
+  PGM
+
+/*=== Initial program to run in a programmer group job =============*/
+/* Called from GRP.                                                 */
+/*    Command to run is in *GDA                                     */
+/*    Library list is inherited from calling job                    */
+/* Simply establishes the job, does setup, and transfers back       */
+/*==================================================================*/
+
+  DCL VAR(&GDA)        TYPE(*CHAR) LEN(512)
+
+/*== Get command to run ============================================*/
+  RTVDTAARA DTAARA(*GDA) RTNVAR(&GDA)
+
+/*=== Set my own attention program for this job ====================*/
+  SETATNPGM PGM(GRP_ATN)
+
+/*=== Fix print files to sensible defaults =========================*/
+  OVRPRTF FILE(QPQXPRTF) PAGESIZE(*N 132)
+
+/*=== And go right back to caller to continue initialization =======*/
+  TFRGRPJOB GRPJOB(*PRV)
+
+/*=== Resume here when selected from menu ==========================*/
+/* -- Run the command specified in the *GDA                   */
+/* -- Hitting the attention key suspends this job and invokes */
+/*    the attention program.  This job may resume, or another */
+/*    job may resume.                                         */
+/* -- Exit from running program cleans up the environment,    */
+/*    then loops back to start the program again.             */
+
+LOOP: +
+  CALL PGM(QCMDEXC) PARM(&GDA 512)
+  RCLRSC
+  RCLACTGRP ACTGRP(*ELIGIBLE) /* Not a good practice in production*/
+  GOTO CMDLBL(LOOP)
+
+ENDPGM: +
+  ENDPGM
@@ -0,0 +1,9 @@
+ GR_LIBL: PGM
+ /*================================================================*/
+ /* Sets the library list for all group jobs. Customize as needed. */
+ /* Called from GRP.                                               */
+ /*================================================================*/
+
+ CHGLIBL    LIBL(LENNONS1 LENNONS2 QGPL QTEMP)
+
+ ENDPGM